Back to Articles page

There are several procedures described on the Internet that will allow you to make OWA the default mail client so that it will open from mailto: hyperlinks in Web pages. Here is an example, which you can save as a .vbs file (e.g. OWAMailto.vbs) using Notepad, and then double-click it to create the required registry values. Remember to change the value of strURL to your normal OWA URL before you double-click it.

' Insert your OWA URL between the quotes below, assigning a value to strURL.
' Remember to begin the URL with https if you use SSL
' Examples: "http://owa.mydomain.com/exchange", "https://192.168.1.1/exchange"
strURL = ""
If strURL <> "" Then
  Set objWSHShell = WScript.CreateObject("WScript.Shell")
  With objWSHShell
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\", _
      "Outlook Web Access", "REG_SZ"
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\Protocols\mailto\", _
      "URL:MailTo Protocol", "REG_SZ"
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\Protocols\mailto\URL Protocol", _
      "", "REG_SZ"
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\Protocols\mailto\EditFlags", _
      &H00000002, "REG_BINARY"
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\Protocols\mailto\DefaultIcon\", _
      "%ProgramFiles%\Outlook Express\msimn.exe,-2", "REG_EXPAND_SZ"
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\shell\open\command\", _
      """%ProgramFiles%\Internet Explorer\iexplore.exe"" ", "REG_EXPAND_SZ"
    .RegWrite "HKLM\SOFTWARE\Clients\Mail\OWA\Protocols\mailto\shell\open\command\", _
      """%ProgramFiles%\Internet Explorer\iexplore.exe""" & _
      " " & strURL & "/?cmd=new&mailtoaddr=%1", "REG_EXPAND_SZ"
    .RegWrite "HKLM\SOFTWARE\Classes\mailto\shell\open\command\", _
      """%ProgramFiles%\Internet Explorer\iexplore.exe""" & _
      " " & strURL & "/?cmd=new&mailtoaddr=%1", "REG_EXPAND_SZ"
  End With
  Set objWSHShell = Nothing
  WScript.Echo "Registry entries successfully created"
Else
  WScript.Echo "You must edit this file in Notepad" & _
  ", and assign a valid OWA URL to the variable strURL"
End If

Unfortunately, the New Mail page ends up being populated with an address that still has mailto: at the beginning.

To get rid of the mailto: part, you will need to edit one of your server-side OWA .js files. Locate the file named frm_ComposeNote.js . At the time of writing, it is in Program Files\Exchsrvr\exchweb\6.5.7651.60\controls although that numbered folder name will change with future service packs. Make a copy of the file, and then open it in Notepad. Some versions of the file appear to be empty, but that is because a lot of blank lines have been added at the top. Scroll down to the function window.onload, which should look like this:

function window.onload()
{
	initRecipCtxMnu(true);

function window.onload()
{

var strMsgTo = document.all.MsgTo.value;
if(strMsgTo.toUpperCase().substring(0, 7) == "MAILTO:")
  document.all.MsgTo.value = strMsgTo.substring(7);

	initRecipCtxMnu(true);

Now the mailto: part of the email address should disappear soon after the form is displayed.

Note - your clients will need to clear their Temporary Internet Files before this will work because the original .js file is usually cached client-side.